Ну а что до нас, то понеслась...

Основы макросов в 2.0:

Сумки и слоты сумок.
Сумки и их слоты все еще можно юзать в макросах, изменился лишь формат их написания.
Пример формата для сумок и слотов:
/use x y
Где x это порядковый номер сумки, а y – это слот в данной сумке (это часть не претерпела изменений в 2.0).
X = Сумки считаются: слева – направо от 4 до 0.
[4] [3] [2] [1] [0]
Y = Слоты считаются: от верхнего левого до нижнего правого по порядку.
Типа такого:
[1] [2] [3] [4]
[5] [6] [7] [8]
[9] [10][11][12]
[13][14][15][16]
Нумерация слотов инвентаря/экипировки персонажа: теперь можно прописывать в макросах одевание/замену шмоток с помощью функции [equipped] и указания номера слота.
0 = ammo
1 = head
2 = neck
3 = shoulder
4 = shirt
5 = chest
6 = belt
7 = legs
8 = feet
9 = wrist
10 = gloves
11 = finger 1
12 = finger 2
13 = trinket 1 (верхний)
14 = trinket 2 (нижний)
15 = back
16 = main hand
17 = off hand
18 = ranged
19 = tabard
20 = first bag (крайняя справа)
21 = second bag
22 = third bag
23 = fourth bag (крайняя слева)

Примеры функций /equip и /use:
/equip <имя шмотки> (можно писать ручками, а можно нажать shift+клик левой кнопкой мыши на шмотку)
/equip <сумка> <слотсумки>
/equipslot <слот экипировки> <имя шмотки>
/use <имя шмотки>
/use <номер слота>
/use <сумка> <слот сумки>
/userandom <шмотка1>, <шмотка2>, <шмотка2> (рандомно поюзать одну из перечисленных вещей)

Список типов шмоток:
http://www.wowwiki.com/ItemType

Типы оружия.
Сдесь приведен список типов оружия, для удобства создания макросов на смену оружия:
Bows
Crossbows
Daggers
Guns
Fishing Pole
Fist Weapons
Miscellaneous
One-Handed Axes
One-Handed Maces
One-Handed Swords
Polearms
Staves
Thrown
Two-Handed Axes
Two-Handed Maces
Two-Handed Swords
Wands

Экшен бары и их слоты:
1: 1 2 3 4 5 6 7 8 9 10 11 12
2: 13 14 15 16 17 18 19 20 21 22 23 24
3: 25 26 27 28 29 30 31 32 33 34 35 36
4: 37 38 39 40 41 42 43 44 45 46 47 48
5: 49 50 51 52 53 54 55 56 57 58 59 60
6: 61 62 63 64 65 66 67 68 69 70 71 72

Выбор иконки макроса для отображения кулдаунов:
Теперь можно выбирать иконка какого приема, будет отображаться на иконке макроса с помощью функции “#show”.
Можно использовать в макросах с функциями /castsequence или /castrandom. Будут отображаться иконки тех спелов, которые вы хотите видеть.
Например:
#show Cold Blood
/castsequence Cold Blood, Eviscerate
Будет всегда отображаться иконка колд блада с его кулдауном.
В то время как тут:
/castsequence Cold Blood, Eviscerate
После применения колд блада иконка будет меняться на эвис, и хрен вы увидите кулдаун колд блада

Кнопки врубающие наши макросы; Left-Click, Right-Click, Mouse-Over (навести курсор) и другая хрень.
Этот раздел будет полезен тем, кто многие действия активирует с помощью кликанья по иконкам – мышкой ( большинство рог, я все таки надеюсь, биндит все на клаву 8) )
В 2.0 нам добавили возможность задавать модификаторы активации на кнопку созданного макроса, это поможет делать макросы - аля два в одном, и тем самым не перегружать интерфейс лишними иконками.

Модификаторы на нажатие макроса (мышка):
button 1 = left-mouse-click,
button 2 = right-mouse-click,
button 3 = center-mouse-click.

Выглядеть это должно следующим образом:
/cast [button:2] Riposte; Sinister Strike
При нажатии на иконку левой кнопкой мыши сработает синистр, при нажатии правой кнопкой мыши сработает репост.

Так же мы можем использовать функцию “target=mouseover”, она позволяет применять некоторые абилки на других игроков, не меняя свою цель:
/cast [target=mouseover] Blind
Как это работает? Мы деремся с игроком А, и при этом хотим кинуть блайнд на игрока Б, раньше нам надо было выбрать в цель игрока Б, кинуть блайнд и снова выбрать игрока А как цель. Теперь, с помощью фунции “target=mouseover” нам этого делать не придется, достаточно лишь навести на игрока Б курсор мыши и нажать на макрос. Игрок Б получит блайнд а вы сможете продолжать дубасить игрока А, не теряя времени на смены цели. (как вы поняли это можно реализовать, только если макрос на блайнд, у вас забинден на какую либо кнопку)

Модификаторы на нажатие макроса (клава): Alt, Ctrl, SHift.
В макросах можно прописывать – какое действие будет произведено в зависимости от нажатых модификаторов.
К примеру:
/cast [modifier:shift/alt/ctrl] Cold Blood; Backstab
/stopcasting
/cast [modifier:shift] Backstab; [modifier:alt] Eviscerate; [modifier:ctrl] Mutilate
Зажимаем <Shift> и при нажатии получаем Cold Blood -> Backstab.
Зажимаем <Alt> и получаем Cold Blood -> Eviscerate.
Зажимаем <Ctrl> и получаем Cold Blood -> Mutilate.
Если модификаторы не зажимаем, то будет просто Backstab.

Макросы на СТЕЛС:

Спамкнопка на стелс:
Позволяет уходить в стелс, без риска выбить себя случайно повторным нажатием.
/cast [nostealth] Stealth

Спамкнопка на шадоумелт:
/cast [nocombat,nostealth] shadowmeld

Спамкнопка на стелс или шадоумелт:
Позволяет уходить в стелс по спамкнопке, если стелс в кулдауне и вы не в комбате, кастанется шадоумелт, при спаме кнопки, как только откулдаунится стелс – вы уйдете в стелс.
/cast [stance:0] stealth
/cast [nocombat,nostealth] shadowmeld

Стелс (Left-Mouse-Click) -> Шадоумелт (Right- Mouse-Click) -> Спамкнопка
/cast [nostealth] Stealth
/cast [button:2,nocombat,nostealth] shadowmeld

Стелс (Left-Click) -> Маунт (Right-Click)
Не спамкнопка!!!
/use [button:2] <имя маунта>
/cast [button:1] stealth

Стелс (спамкнопка) -> Чип шот
/cast [stealth] Cheap Shot; Stealth

Стелс не в комбате -> Ваниш в комбате
/cast [combat] Vanish; [nostealth] Stealth

Гоуж -> Рестелс
/cast [combat] Gouge; Stealth

Гоуж -> Рестелс -> Чип шот -> Синистр
Очередность абилок сделана так, что следующая по очереди должна сработать только после применения предыдущей, при спаме данной кнопки. Если возможен рестелс (вы вышли из комбата) вы его сделаете, затем чипшот и синистр, если же нет, то по истечении кулдауна на гоуж – вы примените его с нова через 20сек (предлагается заменить данным макросом обычный гоуж).
/castsequence reset=20 Gouge, Stealth, Cheap Shot, Sinister Strike
Альтернативный макрос:
Если вы в стелсе, то бьете чип шотом. Если не в стелсе и в комбате, то бьете гоужем, если тот не на кулдауне. Так же вы можете использовать этот макро для рестелса, ибо он не требует гоужа по очередности применения. Очередь автоматически обнулится при смене цели.
/cast reset=target/combat [nostealth,combat] Gouge; [nocombat, nostealth] stealth; [stealth] cheap shot

Макросы на ШАДОУСТЕП:

Шадоустеп -> Амбуш
Делаете шадоустеп и амбуш в 2 нажатия по одной кнопке (иконка шадоустепа с кулдауном).
#show Shadowstep
/castsequence Shadowstep, Ambush

Шадоустеп -> Амбуш -> Смена пушек -> Хемо
Макрос меняет оружие в зависимости от того, в стелсе вы или нет. Если в стелсе то применяет шадоустеп затем амбуш, потом смена оружия и хемо. Если не в стелсе то просто хемо спамкнопка.
/equip [stealth] <Имя дагера>, [nostealth] <Имя меча>
/cast [equipped:daggers, stealth] Shadowstep
/cast [equipped:daggers, stealth] Ambush; [equipped: One-Handed Swords] Hemorrhage

Шадоустеп -> Сап
Первое нажатие – шадоустеп, второе – сап. Ресет через 20сек.
/castsequence reset=20 Shadowstep, Sap
На этот же макро можно довесить просто сап, при нажатии правой кнопкой мыши:
/castsequence reset=20 Shadowstep, Sap
/cast [button:2] Sap
Или использовать модификатор на клаве (shift/ctrl/alt) для Сапа:
/castsequence reset=20 Shadowstep, Sap
/cast [modifier:shift/ctrl/alt] Sap

Премед->Шадоустеп->Амбуш / Бэкстаб
Премед, затем шадоустеп, затем открывающий прием, в примере – амбуш, потом спам кнопка – бс. Если в стелсе - амбушим, если нет, то бэкстабим. Вы можете выбрать другие открывающие приемы и спам приемы для этого макро.
/cast Premeditation
/stopcasting
/cast Shadowstep
/stopcasting
/cast [stealth] Ambush; Backstab

Макросы на Амбуш/Бэкстаб:

Меняем оружие и амбушим:
Нажимаем 1 раз и происходи смена оружия, потом просто спамим кнопку и амбуш примениться как только будет готов.
/equip <имя оружия>
/cast Ambush

Меняем оружие и бэкстабим:
Если у вас не одет дагер, при первом нажатии на макрос, вы меняете оружие на дагер, при втором нажатии делаете бэкстаб и меняете оружие обратно.
/cast Backstab
/run UseContainerItem(x,y)

Амбуш если в стелсе -> Бэкстаб если нет
/cast [stealth] Ambush; Backstab
или...
/cast [nostealth] Backstab; Ambush

Спамкнопка “Атака” -> Бэкстаб
Просто спам атаки, пока нет возможности для бэкстаба (60 энергии, находиться за спиной цели), без выключения автоатаки.
/startattack
/cast Backstab

Макросы на Синистр/Эвис:

5 Синистров -> Эвис
Цикл из 5 синистров и эвиса после них. (Эвиса не будет пока не будут нажаты все 5 синистров или не сменится таргет).
/startattack
/castsequence reset=target Sinister Strike, Sinister Strike, Sinister Strike, Sinister Strike, Sinister Strike, Eviscerate

Синистр по левому клику мыши -> Эвис по правому клику мыши
/cast [button:2] Eviscerate; Sinister Strike

Макросы на Репост:

Синистр + Репост на спамкнопке:
/startattack
/castrandom Sinister Strike, Riposte
Или...
/startattack
/castsequence reset=1.5 Sinister Strike, Riposte

Синистр по левому клику мыши -> Репост по правому клику
/cast [button:2] Riposte; Sinister Strike

ДЛЯ ТРОЛЕЙ: Синистр -> Репост -> Берсерк
/startattack
/castrandom Sinister Strike, Riposte, Berserking

Макросы на Колд Блад:

Колд Блад -> Эвис (отображение иконки и кд колдблада)
#show Cold Blood
/cast Cold Blood
/stopcasting
/cast Eviscerate
Или…
#show Cold Blood
/castsequence reset=180 Cold Blood, Eviscerate

Колд Блад по левому клику мыши -> Эвис по правому
/cast [button:2] Eviscerate; Cold Blood

Премед ->Амбуш по левому клику / Колд блад ->Эвис по правому клику
В одно нажатие левой кнопкой мыши вы делаете премед и амбуш, в одно нажатие правой кнопкой мыши колдблад и эвис.
/cast [button:2] Cold Blood; Premeditation
/stopcasting
/cast [button:2] Eviscerate; Ambush

5 Синистров -> Колд Блад -> Эвис
#show Cold Blood
/startattack
/castsequence reset=180 Sinister Strike, Sinister Strike, Sinister Strike, Sinister Strike, Sinister Strike, Cold Blood, Eviscerate

Колд Блад -> Мутилейт
/cast Cold Blood
/stopcasting
/cast Mutilate

Колд Блад -> Бэкстаб при зажатом шифте / Эвис (Alt) / Мутилейт (Ctrl)
Зажимаем шифт и получаем колдблад и бэкстаб в одно нажатие. Зажимаем вместо шифта альт и получаем колдблад и эвис. Зажимаем контрол – получаем колдблад и мути.
/cast [modifier:shift/alt/ctrl] Cold Blood; Backstab
/stopcasting
/cast [modifier:shift] Backstab; [modifier:alt] Eviscerate; [modifier:ctrl] Mutilate

Колд блад по правому клику -> Чип шот ->Мутилейт -> Кидни -> Мутилейт -> Эвис по левому клику
/cast [button:2] Cold Blood
/castsequence reset=target Cheap Shot, Mutilate, Kidney Shot, Mutilate, Eviscerate
Этот макро позволяет кастануть колдблад в любой момент цепочки по правому клику. Так же ему пофигу на кулдаун колдблада. Если вы хотите мониторить кулдаун колдблада, не забудьте поставить первой строчкой “#show Cold Blood”.

Макросы на Хемо/Гостли:

Гостли -> 5 Хемо
Бьете гостли, а потом 5 раз хемо, через 20 секунд ресет и снова гостли.
/castsequence reset=20 ghostly strike, hemorrhage, hemorrhage, hemorrhage, hemorrhage, hemorrhage
Можно сделать гостли/хемо через рандом, тогда гостли будет использоваться почти сразу же, как откулдаунится:
/castrandom Ghostly Strike, Hemorrhage

Гостли -> 4-е Синистра -> Эвис
Гостли потом 4 синистра и закрываем эвисом. Только надо помнить что у гостли кулдаун, и если цепочка будет завершена раньше, придется подождать =). (Макрос хорош на гринде толстых мобов)
/castsequence reset=target Ghostly Strike, Sinister Strike, Sinister Strike, Sinister Strike, Sinister Strike, Eviscerate

Синистр по левому клику -> Хемо по правому
/cast [button:2] Hemorrhage; Sinister Strike

Хемо по левому клику -> Эвис по правому
/cast [button:2] Eviscerate; Hemorrhage

Хемо -> СнД -> Эвис (еще один макрос на фарм)
/startattack
/castsequence reset=target Hemorrhage, Hemorrhage, Hemorrhage, Hemorrhage, Hemorrhage, Slice and Dice, Hemorrhage, Hemorrhage, Hemorrhage, Hemorrhage, Hemorrhage, Eviscerate

Макросы на эксплоз армор /чип шот/ и т.д. -> без сбивания гоужа / сапа / блайнда:

/cast Expose Armor
/stopattack
Можно попробовать избежать лишнего удара убрав оружие или например взяв в руки рейнджет оружие:
/equip <ranged weapon name>
/cast Expose Armor
/stopattack

Для Чипшота:
/equip <ranged weapon name>
/cast Cheap Shot
/stopattack
Тактика хороша в теории, но тем не менее многие папки ей пользуются, надо лишь немного приловчиться…

Макросы на СнД:

СнД с левого клика -> Эвис с правого
/cast [button:2] Eviscerate; Slice and Dice

5 Синистров -> СнД
/startattack
/castsequence reset=target Sinister Strike, Sinister Strike, Sinister Strike, Sinister Strike, Sinister Strike, Slice and Dice
Добавляем СнД и БлэйдФлури (цепочка на фарм с добавлением блейд флури и снд - СС-СнД-БлэйдФлури-СС-СС-СС-СС-СС-Эвис)
#show Blade Flurry
/startattack
/castsequence reset=120 Sinister Strike, Slice and Dice, Blade Flurry, Sinister Strike, Sinister Strike, Sinister Strike, Sinister Strike, Sinister Strike, Eviscerate

СС+СнД+5СС+Колд Блад+Эвис
#show Cold Blood
/startattack
/castsequence reset=180 Sinister Strike, Slice and Dice, Sinister Strike, Sinister Strike, Sinister Strike, Sinister Strike, Sinister Strike, Cold Blood, Eviscerate

Чип Шот -> СнД (жмем очень быстро)
/castsequence reset=target/combat Cheap Shot, Slice and Dice

“ I.W.I.N. Button!” или игра одним пальцем:
Цепочка: Чипшот->Гоуж->Стелс->Чипшот->СС->Колд Блад->Эвис->Ваниш->Чипшот->Гоуж->СС->СС->Эвис
/castsequence reset=target Cheap Shot, Gouge, Stealth, Cheap Shot, Sinister Strike, Cold Blood, Eviscerate, Vanish, Cheap Shot, Gouge, Sinister Strike, Sinister Strike, Eviscerate